vertex_display.glsl

 
#version 430
 
#ifdef VERTEX_SHADER
layout(location= 0) in vec3 position;
 
layout(binding= 0) buffer invocationData
{
    uint invocations[];
};
 
uniform mat4 mvpMatrix;
uniform mat4 mvMatrix;
 
out vec3 vertex_position;
out vec3 vertex_color;
 
void main( )
{
    gl_Position= mvpMatrix * vec4(position, 1);
    vertex_position= vec3(mvMatrix * vec4(position, 1));
    
    uint n= invocations[gl_VertexID];
    
    // utilise une palette de couleur pour afficher la valeur du compteur
    const vec3 colors[10]= vec3[10](
        vec3(0,0,0), 
        vec3(12,17,115),
        vec3(28,121,255),
        vec3(31,255,255),
        vec3(130,255,17),
        vec3(255,255,14),
        vec3(255,112,22),
        vec3(251,0,20),
        vec3(113,1,14),
        vec3(113,1,14)
    );
    
    if(n < 10) vertex_color= colors[n] / vec3(255);
    else vertex_color= colors[9] / vec3(255);
}
 
#endif
 
#ifdef FRAGMENT_SHADER
out vec4 fragment_color;
 
in vec3 vertex_position;
in vec3 vertex_color;
 
layout(early_fragment_tests) in;
 
void main( )
{
    vec3 l= normalize(-vertex_position);        // l, direction vers la lumiere // la camera est la source de lumiere. (0,0,0) dans le repere camera
    vec3 n= normalize(cross(dFdx(vertex_position), dFdy(vertex_position)));         // n, normale au point p
    float cos_theta= abs(dot(n, l));            // cos theta, angle entre la normale et la direction vers la lumiere
    
    fragment_color= vec4(vertex_color * cos_theta, 1);
}
#endif